Newton's 2nd Law of Motion

New Maple Operators

• ->   The function operator.  Use the dash followed by the greater than symbol to create this operator.  An expression such as can be thought of as defining x as a function of t.  If fact, the assignment

  > x := 2*t+5;

  

  creates an expression represented by x which in many situations Maple automatically interprets as a function of t.  But, Maple also has the ability to think of an object explicitly as a of function a specific variable.  For example,

  > z := t -> 2*t^2;

  

  Interpret the arrow as "is mapped to".  In this case t is mapped to , or the function z maps t to .

  > z(1), z(2), z(3), z(p);

  

  For more examples check out ?->.

• unapply  This operator creates functions out of expressions.  Use unapply to make a function of t from the expression represented by the variable x.

  > f := unapply( x, t );

  

  > f(1), f(2), f(3), f(p);

  

  Note that x has not changed.

  > x;

  

  Perhaps look up ?unapply.

• D   The function differentiation operator.  D takes a function (not an expression) as an argument and returns the derivative of this function as another function.  The only exception to this rule is when a function's derivative is a constant.  In such a case Maple just returns the constant.  In general, whenever Maple finds or produces a constant in a place that it expects to find or produce a function, it automatically assumes that the constant represents a constant function.  Some D examples:

  > z(t), D(z);

  

  > f(t), D(f);

A useful Maple aside: After Maple evaluates a command line containing several expressions separated with commas, you may refer to the results using the selection operator, [ ], numbering the output from left to right starting with 1.

> dz := %%[2];

Click here if you would like to read a Maple oriented review of functions, limits, and derivatives.  The review introduces the limit function, inert functions, two new plot options, and a couple Maple subtleties that could cause some frustration if not understood.

Check out the following commands, and notice how, depending on the context, Maple interprets a symbol like f differently.

> f, z; f(t), z(t);

 

> plot( {f(t),z(t)}, t=-2..2, title=`as parameters to a plot call you need f(t) and z(t)`);

 

 

As parameters to a D call you typically want to use  f  and z.

> D( z ); D( f );

D interprets the symbols like z(t) as the composition of the functions z and t.

> D( z(t) ); D( f(t) );

These results indicate that D uses the chain rule and that the function t has not been defined yet.  Think about the next command.

> D( f(z) );

At this point, in a mathematical context, the symbols f and z represent the functions f and z.  However, in Maple this is not always the case.  As the various commands above illustrate, depending on the context in which they appear, the symbols f, z and t sometimes represent nothing more than variables called f, z and t, and sometimes they represent the functions called f, z and t.  To indicate that you mean the functions f and z in situations where Maple normally interprets symbols such as f and z as variable names, use f(t) and z(t). 

Fair warning: Maple exhibits an inconsistency in its handling of functions as parameters to the plot function.  Suppose g is defined as a function of a single variable, t.  Sometimes plot accepts either g or g(t) and produces the desired graph.  At other times it does not interpret g correctly, and returns incorrect graphs.  Be safe and always use g(t) in the plot command when plotting functions created with ->, unapply, D, or any other function that produces functions as output.

• assume  This function tells Maple to always make some assumption about a variable.  It produces no output, and variables with assumptions on them display a trailing tilde in Maple output.  Select "Assumed Variables" from the Output menu to change the tilde behavior.  Consider the following set of commands.

  > D(5);           # Maple ignores anything in a command line following a # symbol

  

  > D(g);            # D expects a function, and thus assumes g is an as of yet undefined function.  It displays the derivative of such a function as

  

  > assume( g, constant );

  > D(g);

  

  > about ( g );

  Originally g, renamed g~:

    is assumed to be: constant

  For more information on assume and about, place the cursor on assume in your Maple worksheet, then select "Help on assume" from the Help menu.  The assume facilities help page lists all the assumptions that you can place on a variable.

Top

Motion Over Motion

Why Motion instead of just Motion in all the hyperlinks to this section?   Because the often neglected idea in discussions of force is that it's Newton's laws of motion that describe force through statements about motion  --  it's not Newton's laws of force that describe motion.  While solving force problems this second idea is often the perspective, i.e. given the forces on an object, its motion is deduced.  In most physics texts the need to show how to solve subtle and complicated force problems sometimes results in a very quick brushing over of the roots of force: its definition!

The idea is this: If you can find a way to describe an object's position through time, and you know its mass, then Newton's second law of motion provides the tool for finding the net force on the object.  The tool is

Newton's second law of motion defines the net force on an object as its mass multiplied by its acceleration.

Acceleration is a property of motion.   Acceleration is defined as an object's change of velocity through time.  A more mathematically precise definition is that an object's acceleration is the derivative of its velocity with respect to time, t (don't let the "curly d" in the output below bother you, Maple uses it to symbolize both "regular" differentiation and partial differentiation, which is its more typical usage).

Newton's second law, with the appropriate substitution, now looks like

An object's velocity is defined as its change of position through time, or more precisely, as the derivative of its position with respect to time, t.  Define r as the position vector of an object in some coordinate system, then

From just above we know that net force is mass multiplied by the first derivative of velocity with respect to time, t.  Substituting yields another useful form of Newton's second Law of Motion:

This form of Newton's second law enables you to find the net force if you know an object's mass and its position through time.

Top

> restart;

Note: Do not hesitate to use Maple help or the Maple Index provided in this tutorial to look up information on the use of Maple operators.

Suppose you know that the following functions of time describe the position of a 2 kg object in a horizontal xy-plane during the time interval t = 0..8*Pi s.  To avoid using the boring phrase "the object" over and over again, we will call the object stinky.

> x := t -> t*cos( t );

> t*sin( t );

> y := unapply( %, t );

Execute a parametric plot to see how stinky moves in the plane for t = 0..8*Pi s.

> plot( [x(t), y(t), t=0..8*Pi], labels=["x","y"], scaling=constrained );

> v[x] := D(x);

> v[y] := D(y);

As an interesting aside, what do the graphs of vs. t and vs. t look like?  The plot below is a multiple plot, because in this case a parametric plot does not yield much information.

> plot( {v[x](t), v[y](t)}, t=0..8*Pi, scaling = constrained );

The multiple plot above shows the magnitude and direction for each of the component vectors of stinky's velocity.

Composing the component vectors with head to tail vector addition creates a right triangle whose hypotenuse is the velocity vector.  It's magnitude is the length of the hypotenuse.  Thus,

> speed := t -> sqrt( v[x](t)^2 + v[y](t)^2 );

> plot( speed(t), t=0..8*Pi, labels=["t","speed"], title=`speed as a function of t` );

Why does it make sense that stinky's speed increases as time progresses?

> a[x] := D( v[x] );

> a[y] := D( v[y] );

If you want, make a multiple plot of stinky's x and y-accelerations.  The plot below shows how the magnitude of stinky's acceleration changes with time.

> plot( sqrt(a[x](t)^2+a[y](t)^2), t=0..8*Pi, title=`magnitude of acceleration as a function of t`, labels=["t","accel"] );

Given the symmetry of stinky's movement, and the symmetry of the equations describing the movement, it is not surprising that both the graphs of its x and y-accelerations and velocities, and the graphs of its acceleration magnitude and velocity magnitude (speed) are so similar, respectively.

The net force on stinky breaks up into component forces, and as with position, velocity, and acceleration, since we use the xy-plane in this case, they can be placed easily along the x and y-axes.

> F[x] := unapply( 2*a[x](t), t );

> F[y] := unapply( 2*a[y](t), t );

Important concept: In this example we don't know the location of the source(s) of the force(s) acting on stinky.  Based on our knowledge of stinky's position, we have only found a set of equations that describes the net force vector (the vector sum of all the forces acting on stinky).  Given the choice of coordinate system, it is easy for us to break the net force vector into two component vectors, one which lies along the x-axis, and one which lies along the y-axis.  In this example, the component vectors are mathematical conveniences, they do not yield any information about the location of the source(s) of the force(s) on the object.  In other situations you might actually know the source of some or all of the forces on an object.  If, and only if, you choose a coordinate system in which each of the known forces lies along a coordinate axis, then you can say that component vectors such as and actually tell you something about the positions of the sources of the forces on an object.

At this point the graph of how the magnitude of the net force changes with time should not surprise you.  The colon supresses output, it does not supress the calculation.  Maple creates the plot object, and places it in temporary memory. You can access it later with the ditto operators.

> plot( sqrt(F[x](t)^2+F[y](t)^2), t=0..8*Pi, labels=["t", "F[net]"], title=`magnitude of net force as a function of t` ):  

The path of stinky in this example is actually a typical path induced on particles in cyclotrons (your physics book probably contains a discussion of cyclotrons, also).  Cyclotrons accelerate nuclear particles.  Using these particle accelerators, physicists smash particles together at high speeds and record the movement of particles created by the smashing event.  They place a coordinate system on the record of the event, and use methods similar to the one in this section to describe the net force acting on a particle.

Physicists can use the post collision record to look for new particles.   Where there is a force, there is a material source of the force.  This rule of thumb is the key to detecting unknown particles.  They sum up the known forces on an observed post-smash particle -- the sources of such forces might be electromagnetic forces in the cyclotron, the attraction of other known particles in the post smash environment, etc.  If the vector sum of these known forces does not equal the net force vector on a particle (computed from the record with the help of Newton's 2nd law), then they know to look for other as yet unseen particles that were created by the smashing event.  The logic being that an undetected particle is the most likely source of the additional force needed to make the known forces sum up to the net force. 

The planet Uranus was discovered in a similar manner, not by smashing planets together, but by noting that the sum of the known forces on the planet Neptune did not account accurately for its observed motion, and then looking in the sky where the "missing" source force most likely would be.

One more thing: Unlike the assignment statements that create the functions , , , and , the assignment statements that create the functions and need to use unapply.  Why? 

Newton's 2nd Law Problem Set         Top        Work and Kinetic Energy

Tutorial Index         Maple Index         How to...        Problem Set Index

Please send me any polite comments, suggestions, or corrections.